Hover mouse on each icon for information

;Rain/show script
;Create a rain or snow picture that is taller than the room.
;Put the picture in the spot multiple (e.g., 10) times.
;Customize the information between the lines of asterisks.
;Then say "setpictures " to automatically set the picture locations.
;Note, you must be an owner/operator to do this.
;Other useful commands provided are:
;Say "reset " to set the spot to the first picture.
;Say "mp" to find the current mouse position.
ON ENTER
{
nbrpics GLOBAL
;***Set the number of pictures***
15 nbrpics =
;***end of data***
0 ME SETSPOTSTATELOCAL
0 ME SETALARM
}
ON OUTCHAT
{
nbrpics GLOBAL
{
{
;*************************************************
;Set the picture parameters.
;Start and stop positions are relative to the door.
;You must be an Owner/Operator for the script to work.
0 start_x =
-50 start_y =
0 stop_x =
0 stop_y =
;*************************************************
nbrpics 1 - steps =
stop_x start_x - range_x =
stop_y start_y - range_y =
;
;Move the pictures. Multiply before divide to reduce error!
;
0 i =
{ i ME SETSPOTSTATE
start_x range_x i * steps / + start_y range_y i * steps / + ME SETPICLOC
i ++
} { i nbrpics 1 - <= } WHILE
0 ME SETSPOTSTATE
0 inout =
"" CHATSTR =
} "$1" GREPSUB ATOI ME == IF
} CHATSTR "^setpictures ([0-9]+)" GREPSTR IF
;
{
{ 0 ME SETSPOTSTATE
0 inout =
"" CHATSTR =
} "$1" GREPSUB ATOI ME == IF
} CHATSTR "^reset ([0-9]+)" GREPSTR IF
;
{ MOUSEPOS y = x =
"@" x ITOA & " " & y ITOA & " x = " & x ITOA & ", y = " & y ITOA & LOCALMSG
"" CHATSTR =
} CHATSTR "mp" == IF
}
ON ALARM
{
nbrpics GLOBAL
ME GETSPOTSTATE 1 + nbrpics % ME SETSPOTSTATELOCAL ;cycle up
30 ME SETALARM
}