Apartment Script MultiOwner

Knowledgebase

Storm Palace Hosting > Storm Hosting Help Desk > Knowledgebase

Apartment Script MultiOwner

Solution ;Apartment Script by Glide
;rescripted by Ravenwood Partsong for Multiple Owners 2014
;ravenwoodhs@yahoo.com
;The script is set up so the first person in the room is the room owner.
;To assign this room permanently to someone by name...
;remove the 2nd line in the ON ENTER section which looks like this:
;rowner GLOBAL 0 ROOMUSER WHONAME rowner =
;and in its place, put this line:
;rowner GLOBAL "RoomOwnerName" rowner =
;Don't use the semi-colon (;) at the beginning of the line...
;and put the room owner's name where it says RoomOwnerName
;
;Near the bottom of the script, in the ON ALARM section...
;change the room number to the room number that people are kicked to.
;
;This script can be sensitive to low flood limits.
;
ON ENTER {
;rowner GLOBAL 0 ROOMUSER WHONAME rowner =
rowner2 GLOBAL ".Star~B~ SpH" rowner2 =
rowner GLOBAL "§ünshàdôw×§}{" rowner =
rkick GLOBAL 0 rkick =
{ "Welcome to your room, " USERNAME & ". Look in your log window for a list of commands." & LOCALMSG
roomcomm GLOBAL {
{ LOGMSG }
[
""
"ROOM COMMANDS:"
""
";kick"
";gag"
";ungag"
";propgag"
";unpropgag"
";pin"
";unpin"
";freeze"
";unfreeze"
";avlock"
";avunlock"
""
"You must whisper the commands."
"Type \"help\" to see this list again."
""
] FOREACH
} roomcomm DEF
roomcomm EXEC
} USERNAME rowner2 == USERNAME rowner == OR IF
}
ON INCHAT {
rowner2 GLOBAL rowner GLOBAL rpin GLOBAL rgag GLOBAL rkick GLOBAL
rpgag GLOBAL freeze GLOBAL frz GLOBAL avlock GLOBAL
avlck GLOBAL fx GLOBAL fy GLOBAL
{
{ 1 rgag = } CHATSTR ";gag" == WHOCHAT WHONAME rowner2 == WHOCHAT WHONAME rowner == OR AND IF
{ 0 rgag = } CHATSTR ";ungag" == WHOCHAT WHONAME rowner2 == WHOCHAT WHONAME rowner == OR AND IF
{ 1 rkick = 1 ME SETALARM
} CHATSTR ";kick" == WHOCHAT WHONAME rowner2 == WHOCHAT WHONAME rowner == OR AND IF
{ 1 rpgag = 0 avlock = 1 ME SETALARM
} CHATSTR ";propgag" == WHOCHAT WHONAME rowner2 == WHOCHAT WHONAME rowner == OR AND IF
{ 0 rpgag = } CHATSTR ";unpropgag" == WHOCHAT WHONAME rowner2 == WHOCHAT WHONAME rowner == OR AND IF
{ 1 rpin = 0 avlock = 0 freeze = 1 ME SETALARM
} CHATSTR ";pin" == WHOCHAT WHONAME rowner2 == WHOCHAT WHONAME rowner == OR AND IF
{ 0 rpin = NAKED } CHATSTR ";unpin" == WHOCHAT WHONAME rowner2 == WHOCHAT WHONAME rowner == OR AND IF
{ 1 freeze = POSX fx = POSY fy =
POSX ITOA " " & POSY ITOA & " SETPOS" & frz = 1 ME SETALARM
} CHATSTR ";freeze" == WHOCHAT WHONAME rowner2 == WHOCHAT WHONAME rowner == OR AND IF
{ 0 freeze = } CHATSTR ";unfreeze" == WHOCHAT WHONAME rowner2 == WHOCHAT WHONAME rowner == OR AND IF
{ 1 avlock = 0 i = "[" { " " i USERPROP ITOA & & i ++ }
{ i NBRUSERPROPS < } WHILE " ] SETPROPS" & avlck = 1 ME SETALARM
} CHATSTR ";avlock" == WHOCHAT WHONAME rowner2 == WHOCHAT WHONAME rowner == OR AND IF
{ 0 avlock = } CHATSTR ";avunlock" == WHOCHAT WHONAME rowner2 == WHOCHAT WHONAME rowner == OR AND IF
} USERNAME rowner2 == USERNAME rowner == OR NOT IF
}
ON OUTCHAT {
rgag GLOBAL rowner2 GLOBAL rowner GLOBAL
{ { "" CHATSTR = } rgag IF } USERNAME rowner2 == USERNAME rowner == OR NOT IF
{ comm =
{ "" CHATSTR = "You must whisper the commands." LOCALMSG
} comm CHATSTR == WHOTARGET NOT AND USERNAME rowner2 == USERNAME rowner == OR AND IF
} [ ";kick" ";gag" ";ungag" ";propgag" ";unpropgag" ";unpin"
";pin" ";freeze" ";unfreeze" ";avlock" ";avunlock" ] FOREACH
{ roomcomm GLOBAL roomcomm EXEC "" CHATSTR =
} CHATSTR "help" == USERNAME rowner2 == USERNAME rowner == OR AND IF
}
ON ALARM {
rowner2 GLOBAL rowner GLOBAL rpin GLOBAL rpgag GLOBAL rkick GLOBAL
freeze GLOBAL frz GLOBAL avlock GLOBAL avlck GLOBAL
fx GLOBAL fy GLOBAL
2 ME SETALARM
{
{ { [ 1280 ] SETPROPS 490 362 SETPOS
} POSX 490 == POSY 362 == AND NOT IF
{ [ 1280 ] SETPROPS } 1280 TOPPROP == NOT IF } rpin IF
{ NAKED } rpgag NBRUSERPROPS AND IF
{ { frz STRTOATOM EXEC } POSX fx == POSY fy == AND NOT IF } freeze IF
{ { avlck STRTOATOM EXEC } 0 i = "["
{ " " i USERPROP ITOA & & i ++ } { i NBRUSERPROPS < } WHILE
" ] SETPROPS" & dif = dif avlck == NOT IF } avlock IF
;change room number below to the room people are kicked to
{ 86 GOTOROOM } rkick IF
} USERNAME rowner2 == USERNAME rowner == OR NOT IF
}

Was this article helpful? yes / no

Article details

Article ID:	349
Category:	Room Scripts
Date added:	03-26-2014 20:42:34
Views:	806
Rating (Votes):	(0)

<< Go back