Hover mouse on each icon for information

Jukeboxes

An ON SELECT jukebox would look like this.

ON SELECT {
[ ")breathe"
")dntspk"
")bittersw"
")perfectdrug" ] DUP LENGTH RANDOM GET SAY
}

------------------------------------------------------------

An ON OUTCHAT saying the word 'next' to start the songs would look like this.

ON OUTCHAT {
{ [ ")breathe"
")dntspk"
")bittersw"
")perfectdrug" ] DUP LENGTH RANDOM GET SAY
"" CHATSTR = } CHATSTR "next" == IF
}

-----------------------------------------------------------------

Here is a jukebox where if you click the juke, you are given a list of the titles. After that, you just type the name of the song you want to hear.

ON ENTER {
titles GLOBAL
{ [ "openarms" "endlesslove" "titanic" ] sngarray = } titles DEF
"Click on the jukebox for a list of the songs in this room." LOCALMSG
}
ON SELECT {
titles GLOBAL
titles EXEC
"@500 0 To play the song, type one of the following names: " { & ", " & } sngarray FOREACH LOCALMSG
}

ON OUTCHAT {
titles GLOBAL
titles EXEC
{ temp =
{ MIDISTOP
CHATSTR MIDIPLAY
CHATSTR SOUND
"" CHATSTR =
} CHATSTR temp == IF
} sngarray FOREACH
{ MIDISTOP
"" CHATSTR =
} CHATSTR "ms" == IF
}

-------------------------------------------------------------------------------

;Foxys Jukebox

ON ENTER
{ { "Type In List To Get Song List!" statusmsg }170 ALARMEXEC
"This is the same script as Midi Jukebox- PC, except that everyone hears the
midi, not just you." LOCALMSG
}
ON INCHAT {
[ "blackbrd" "onesweet" "sweetlady" ] midis =
{ MIDISTOP } CHATSTR "ms" == IF
{ { md =
{ MIDISTOP CHATSTR SOUND CHATSTR MIDIPLAY
} CHATSTR md == IF
} midis FOREACH
} DATETIME 0 > IF
{ "The midi names are: " { + " " + } midis FOREACH LOCALMSG
} CHATSTR "list" == WHOCHAT WHOME == AND IF
}

;Foxys Jukebox GLOBAL'd
;To put in your gate:
ON SIGNON { midifunction GLOBAL
{
[ "blackbrd" "onesweet" "sweetlady" ] midis =
{ MIDISTOP } CHATSTR "ms" == IF
{ { md =
{ MIDISTOP CHATSTR SOUND CHATSTR MIDIPLAY
} CHATSTR md == IF
} midis FOREACH
} DATETIME 0 > IF
{ "The midi names are: " { + " " + } midis FOREACH LOCALMSG
} CHATSTR "list" == WHOCHAT WHOME == AND IF
} midifunction DEF
}

Then put this in all the rooms you want the midis to be available in:
ON INCHAT { midifunction GLOBAL midifunction EXEC }

-----------------------------------------------------------------------------------------

This would work as a DJ script.

;written by Foxy
ON INCHAT {
{ [ "midiname0" "midiname1" "midiname2" "midiname3" "etc..." ]
"$1" GREPSUB ATOI GET MIDIPLAY
} WHOCHAT WHONAME "^[*]" GREPSTR CHATSTR "^;pl([0-9]+)$" GREPSTR AND IF
}

To run it, you need to have someone with a wizard's badge on say ;pl0 to
;plwhatever is your highest number. Note that this won't d/l the midis to
people that don't have it, you'll need to provide for that separately.